Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

set

Доступность

Flash Player 6.

Синтаксис

function set property(varName) {
  // ваш код
}

Замечание: чтобы использовать данную спецификацию члена класса, Вы должны указать использование ActionScript 2.0 и Flash Player 6 (или более позднюю версию) на закладке Flash в диалоговом окне Publish Settings вашего FLA файла. Это ключевое слово может быть использовано только во внешних файлах с классами, но никак не в коде, введенном на панели Actions..

Параметры

property Слово, определяющее имя свойства, значение которого будет устанавливаться; значение должно быть таким же, как и в соответствующем методе с командой get.

varName Имя локальной переменной, хранящей значение.

Возвращает

Ничего.

Описание

Ключевое слово; позволяет реализовывать неявное изменение свойств объекта, принадлежащего классу, созданному во внешнем файле. Благодаря этому Вы можете переопределять значение свойства так, как пожелаете, при этом не обращаясь к свойству напрямую. Get/set методы есть аналог Object.addСвойство() в ActionScript 1. Для более подробной информации смотри "Getter/setter методы " в Использовании ActionScript во Flash.

Пример

В следующем примере создается класс Login и на его примере показывается использование ключевого слова set для изменения значения private свойств класса:

class Login {
  private var loginUserName:String;
  private var loginPassword:String;
  public function Login(param_username:String, param_password:String) {
    this.loginUserName = param_username;
    this.loginPassword = param_password;
  }
  public function get username():String {
    return this.loginUserName;
  }
  public function set username(param_username:String):Void {
    this.loginUserName = param_username;
  }
  public function set password(param_password:String):Void {
    this.loginPassword = param_password;
  }
}

Во FLA или AS файле в той же директории, что и Login.as, введите следующий код в первый кадр главного Таймлайна:

var gus:Login = new Login("Gus", "Smith");
trace(gus.username); // Выведет: Gus
gus.username = "Rupert";
trace(gus.username); // Выведет: Rupert

В данном примере get метод вызывается при выводе значения на панель Output. Set метод работает лишь при присваивании значения:

gus.username = “Rupert”;

См. также

get, Object.addСвойство()

Смотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление